debug目录下出现很多语言包，怎样去掉
为什么编译后程序目录下有好几个语言包文件夹？如de、es、ja 等等？每次编译后都自动拷贝我将“程序集信息”中的“非特定语言”改成中文（简体）也不行
同问！！！！！！！！！ 继续问。请高手。 以下内容存为 gacinstall.cmd
@echo off
if "%1"=="/?" goto help:
if "%1"=="" goto help:
goto start:
:help
@echo on
@echo Installs/unistalls localized satellite assemblies into/from the GAC
@echo.
@echo GACINSTALL
@echo.
@echo /u Unistall localized assemblies
@echo culture Culture name of a satellite asembly to install/unistall
@echo.
@echo Usage:
@echo.
@echo GACINSTALL he-IL
@echo Installs the hebrew satellite assemblies from the current folder's 'he-IL' subfolder
@echo.
@echo GACINSTALL /u he-IL
@echo Uninstalls the hebrew satellite assemblies
@echo.
@echo GACINSTALL /u
@echo Uninstalls all the installed satellite assemblies
@echo.
@echo off
goto quit
:start
REM set GACUtil="%ProgramFiles(x86)%\Microsoft SDKs\Windows\v7.0A\Bin\gacutil.exe"
REM set GACUtil="%ProgramFiles(x86)%\Microsoft SDKs\Windows\v8.0A\bin\NETFX 4.0 Tools\gacutil.exe"
set GACUtil="%ProgramFiles(x86)%\Microsoft SDKs\Windows\v8.1A\bin\NETFX 4.5.1 Tools\gacutil.exe"
if not exist %GACUtil% (
echo could not find gacutil.exe
goto quit
)
if "%1"=="/u" goto unistall:
set CultureDir=
set DirKey=
if not "%1"=="" set CultureDir=%1"\\"
if not "%CultureDir%"=="" set DirKey=/S
@echo on
FOR /F "usebackq delims==" %%i IN (`dir /B %DirKey% %CultureDir%*.dll`) DO %GACUtil% /i "%%i"
@echo off
goto quit
:unistall
set CultureDir=
set CultureOptions=
if not "%2"=="" set CultureDir=%2"\\"
if not "%2"=="" set CultureOptions=,Culture=%2
echo CultureOptions=%CultureOptions%
FOR /F "usebackq delims==" %%i IN (`dir /B /S %CultureDir%*.dll`) DO %GACUtil% /u %%~ni%CultureOptions%
:quit
以下内容存为 uninstall_Others.cmd
@echo off
::BatchGotAdmin
:---------------------------------------------------------------------------
REM--> Check for permissions
>nul 2>&1 cd/d "%homedrive%\Recovery"
REM --> If error flag set, we do not have admin.
if errorlevel 1 (
echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
if '%1'=='UACdone' (shift & goto gotAdmin)
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getAdmin.vbs"
echo UAC.ShellExecute "%~0", "UACdone", "", "runas", 1 >> "%temp%\getAdmin.vbs"
"%temp%\getAdmin.vbs"
exit /B
:gotAdmin
rem if exist "%temp%\getAdmin.vbs" ( del "%temp%\getAdmin.vbs" )
cd /d %~dp0
:---------------------------------------------------------------------------
call gacinstall /u de
call gacinstall /u es
call gacinstall /u ja
call gacinstall /u ru
timeout /t 5
把这两个批处理放到安装目录的 Bin\Framework 下面，
双击执行 uninstall_Others.cmd 将反注册默认安装的外国语言资源，
然后删除debug目录下几个资源目录就行了，以后vs将不再拷贝这些资源
矿工码农g 发表于 2015-7-21 15:18
以下内容存为 gacinstall.cmd
@echo off
if "%1"=="/?" goto help:
高手啊，十分感谢！ nandi_1 发表于 2015-7-23 21:27
高手啊，十分感谢！
还有一个sq目录还是删不掉，在批处理文件里加了一行
call gacinstall /u sq
也不行 本帖最后由 矿工码农g 于 2015-7-24 03:26 编辑
我的DevExpress安装目录和开发工程目录里都没有sq这样的子目录哦
不错，好东西！我终于把那几个烦人的语言包给干掉了！
页:
[1]